;$VER: CronTask Install 1.0 (Sep 25 1994) 
;Copyright  1994 JoJoSoft Development. All rights reserved.

;=============================================================================
; English strings
;=============================================================================

(if (= @language "english")
(
	(set #default_language 1)

	(set #install-msg
		(cat "\n\nInstalling CronTask in your system.\n\n"
	  	   "CronTask  1994 JoJoSoft Development.\n"
	    	 "All rights reserved." ))

	(set #AreYouSureUnInstall "\\n\\n\\n\\n\\n\\n\\n\\n\\n\\n\\n\\n\\nAre you sure you want to uninstall CronTask.")
	(set #UnInstallFinished "\\n\\n\\n\\nCronTask uninstall is finished. CronTask has sadly \\nenough been removed from your system.")
	(set #ChooseDir	"\nChoose destination directory\nfor ")
	(set #GetUnPathText (cat #ChooseDir "the uninstallation script\n"))
	(set #CopyCronTaskText (cat #ChooseDir "CronTask\n"))
	(set #CopyCronPrefsText (cat #ChooseDir "CronPrefs\n"))
	(set #CopyCronLibText "\nCopying 'cronserver.library' to LIBS:.\n")
	(set #IconEnhPrompt "\n\n\n\n\n\n\n\nWhich icon set do you want to install?")
	(set #IconEnhGadgets1 "Standard (4 colors)")
	(set #IconEnhGadgets2 "Enhanced (8 colors)")
	(set #DocPathPrompt (cat #ChooseDir "the documention\n"))
	(set #RegFormPrompt "\n\n\n\n\n\n\n\nCronTask installation gives you the opportunity to print the registration form.")
	(set #RegFormChoices1 "Do not print registerform")
	(set #RegFormChoices2 "Print registerform")

	(set #wrong-kick (cat "This program is a heavy user of OS 2.x. Buy it, you wont regret it! For starters you could use the best Cron ever." ))

	(set #which-language (cat "\nWhich languages should be installed?" ))
	(set #which-language-help
		(cat "\nOne of the best features of Workbench 2.1 was\n"
		     "the abilty to work in different languages.\n"
		     "CronTask uses this feature. If your language\n"
		     "is avilable then select it and make the most\n"
		     "out of CronTask\n\n"
			  @askoptions-help ))

	(set #which-document (cat "\nWhich documentations should be installed?" ))
	(set #which-document-help
		(cat "Hjlp!!!"
				@askoptions-help ))

	(set #Ending (cat "\n\nWe congratulate you to your fine choice of Cron. Make\n"
							 "sure to read the manual carefully so you don't\n"
							 "missout on any of the great features of CronTask.\n\n\n"
							 "An unistall script has been created: "))

))

;=============================================================================
; Svenska strngar
;=============================================================================

(if (= @language "svenska")
(
	(set #default_language 2)

	(set #install-msg
		(cat "\n\nInstallerar CronTask i ditt system.\n\n"
	  	   "CronTask  1994 JoJoSoft Development.\n"
	    	 "Alla rttigheter reserverade."
	))

	(set #AreYouSureUnInstall "\\n\\n\\n\\n\\n\\n\\n\\n\\n\\n\\n\\n\\nr du sker p att du vill avinstallera CronTask?")
	(set #UnInstallFinished "\\n\\n\\n\\nCronTask avinstallation r klar. CronTask har\\nsorgligt nog blivit borttaget frn ditt system.")
	(set #ChooseDir	"\nVlj en katalog fr\n ")
	(set #GetUnPathText (cat #ChooseDir "avinstallations scriptet\n"))
	(set #CopyCronTaskText (cat #ChooseDir "CronTask\n"))
	(set #CopyCronPrefsText (cat #ChooseDir "CronPrefs\n"))
	(set #CopyCronLibText "\nKopierar 'cronserver.library' till LIBS:.\n")
	(set #IconEnhPrompt "\n\n\n\n\n\n\n\nVilken ikon uppsttning vill du installera?")
	(set #IconEnhGadgets1 "Standard (4 frgers).")
	(set #IconEnhGadgets2 "Frfinat (8 frgers).")
	(set #DocPathPrompt (cat #ChooseDir "dokumenten\n"))
	(set #RegFormPrompt "\n\n\n\n\n\n\n\nCronTask installerare ger dig mjligheten att skriva ut registrerings formlret.")
	(set #RegFormChoices1 "Skriv inte ut registrerings formulret.")
	(set #RegFormChoices2 "Skriv ut registrerings formulret.")

	(set #wrong-kick (cat "Detta program r en tung anvndare av OS 2.x. Kp det, du kommer inte ngra dig! Till att brja med kan du d anvnda den bsta Cron ngonsin." ))

	(set #which-language (cat "\nVilka sprk ska bli installerade?" ))
	(set #which-language-help
		(cat "\nEn av dom bsta finesserna i Workbench 2.1 var\n"
		     "mjligheten att arbeta i olika sprk.\n"
				 "CronTask anvnder denna finess. Om ditt sprk finns\n"
				 "tillgngligt, vlj det och gr det mesta av CronTask.\n"
			  @askoptions-help ))

	(set #which-document (cat "\nVilka dokument ska bli installerade?" ))
	(set #which-document-help
		(cat "Hjlp!!!"
				@askoptions-help ))

	(set #Ending (cat "\n\nVi gratulerar till ditt fina val av Cron. Se till\n"
							 "att lsa manualen noggrant s du inte missar ngra av\n"
							 "CronTask's alla finesser.\n\n\n"
							 "Ett avinstallations script har skapats: "))
))

;--------------------------
; Script's real beginning.
;--------------------------

(if (< (/ (getversion) 65536) 37)
(
    (abort #wrong-kick)
))

(user 2)
(welcome (message #install-msg))

(complete 0)

(set DefUn-Path
	(askdir
		(prompt #GetUnPathText)
		(help @askdir-help)
		(default "RAM:")
	)
) 

(copyfiles
	(newname "Un-Install CronTask.info")
	(source "English.info")
	(dest DefUn-Path)
)

(tooltype
	(dest (cat DefUn-Path "Un-Install CronTask"))
	(settooltype "SCRIPT" "Un-Install CronTask")
	(settooltype "MINUSER" "EXPERT")
	(noposition)
)

(working #install-msg)

(run (cat "echo >\"" DefUn-Path "Un-Install CronTask\""))
(set Un-Path (cat "echo >>\"" DefUn-Path "Un-Install CronTask\""))

(run Un-Path "\";$VER: CronTask Un-Install 1.0 (Sep 25 1994)\"")
(run Un-Path "\";Copyright  1994 JoJoSoft Development. All rights reserved\"")
(run Un-Path "\"(complete 0)\"")
(run (cat Un-Path "\"(user 2)\""))
(run (cat Un-Path "\"(welcome (message '" #AreYouSureUnInstall "'))\""))
(run (cat Un-Path "\"(delete '" DefUn-Path "Un-Install CronTask')\""))
(run (cat Un-Path "\"(delete '" DefUn-Path "Un-Install CronTask.info')\""))
(run (cat Un-Path "\"(run 'delete ENV:Cron all')\""))
(run (cat Un-Path "\"(run 'delete ENVARC:Cron all')\""))
(run Un-Path "\"(complete 10)\"")

;--------------------------------------------------
; Copying CronTask, Cronprefs & cronserver.library.
;--------------------------------------------------

(set CronTask-Path
	(askdir
		(prompt #CopyCronTaskText)
		(help @askdir-help)
		(default "SYS:WBStartup/")
	)
)

(copyfiles
	(source "/CronTask")
	(dest CronTask-Path)
	(infos)
)

(complete 8)

(working #install-msg)

(run (cat Un-Path "\"(run '" CronTask-Path "CronTask q')\""))
(run Un-Path "\"(complete 20)\"")
(run (cat Un-Path "\"(delete '" CronTask-Path "CronTask.info')\""))
(run (cat Un-Path "\"(delete '" CronTask-Path "CronTask')\""))
(run Un-Path "\"(complete 30)\"")

(complete 16)

(set CronPrefs-Path
	(askdir
		(prompt #CopyCronPrefsText)
		(help @askdir-help)
		(default "SYS:Prefs/")
	)
) 

(copyfiles
	(source "/CronPrefs")
	(dest CronPrefs-Path)
	(infos)
)

(complete 24)

(working #install-msg)

(run (cat Un-Path "\"(delete '" CronPrefs-Path "CronPrefs')\""))
(run Un-Path "\"(complete 40)\"")
(run (cat Un-Path "\"(delete '" CronPrefs-Path "CronPrefs.info')\""))
(run Un-Path "\"(complete 50)\"")

(complete 32)

(copylib
	(prompt #CopyCronLibText)
	(help @copylib-help)
	(source "/Libs/cronserver.library")
	(dest "LIBS:")
	(confirm)
)

(working #install-msg)

(run (cat Un-Path "\"(delete 'Libs:cronserver.library')\""))
(run Un-Path "\"(complete 60)\"")

(complete 40)

;-----------------
; Copying icon's.
;-----------------

(set #Enhanced
	(askchoice
		(prompt #IconEnhPrompt)
		(default 0)
		(choices #IconEnhGadgets1 #IconEnhGadgets2)
		(help "Hjlp!!!")
	)
)

(complete 56)

(if #Enhanced
(
	(copyfiles
		(source "/Icons/CronTask.info")
		(dest CronTask-Path)
	)

	(copyfiles
		(source "/Icons/CronPrefs.info")
		(dest CronPrefs-Path)
	)
))

(complete 64)

(tooltype
	(dest (cat CronTask-Path "CronTask"))
	(settooltype "DONOTWAIT" "")
	(noposition)
)

(tooltype
	(dest (cat CronPrefs-Path "CronPrefs"))
	(noposition)
)

(complete 69)

;-----------------------
; Copying documentation.
;-----------------------

(set documentation
	(askoptions
		(prompt #which-document)
		(help #which-document-help)
		(choices
			"English"
			"Svenska")
			(default #default_language)
		)
)

(complete 72)

(set count 0)
(set #askdocpath 1)

(while (set doc (select count
								"english"
								"svenska"
								""))
(
	(if (IN documentation count)
	(
		(if #askdocpath
		(
			(set #askdocpath 0)
			
			(set Doc-Path
				(askdir
					(prompt #DocPathPrompt)
					(help @askdir-help)
					(default CronPrefs-Path)
				)
			) 
		))

		(if (= count 0)
		(
			(copyfiles
				(source "/Docs/CronTask.guide.eng")
				(dest Doc-Path)
				(infos)
			)

			(copyfiles
				(source "/Docs/Register_form.eng")
				(dest Doc-Path)
			)

			(if #Enhanced
			(
				(copyfiles
					(newname "CronTask.guide.eng.info")
					(source "/Icons/Doc.info")
					(dest Doc-Path)
				)
			))

			(tooltype
				(dest (cat Doc-Path "CronTask.guide.eng"))
				(noposition)
			)

			(working #install-msg)

			(run (cat Un-Path "\"(delete '" Doc-Path "CronTask.guide.eng')\""))
			(run (cat Un-Path "\"(delete '" Doc-Path "CronTask.guide.eng.info')\""))
			(run (cat Un-Path "\"(delete '" Doc-Path "Register_form.eng')\""))
		))

		(if (= count 1)
		(
			(copyfiles
				(source "/Docs/CronTask.guide.sve")
				(dest Doc-Path)
				(infos)
			)

			(copyfiles
				(source "/Docs/Register_form.sve")
				(dest Doc-Path)
			)

			(if #Enhanced
			(
				(copyfiles
					(newname "CronTask.guide.sve.info")
					(source "/Icons/Doc.info")
					(dest Doc-Path)
				)
			))

			(tooltype
				(dest (cat Doc-Path "CronTask.guide.sve"))
				(noposition)
			)

			(working #install-msg)

			(run (cat Un-Path "\"(delete '" Doc-Path "CronTask.guide.sve')\""))
			(run (cat Un-Path "\"(delete '" Doc-Path "CronTask.guide.sve.info')\""))
			(run (cat Un-Path "\"(delete '" Doc-Path "Register_form.sve')\""))
		))
	))

	(set count (+ count 1))
))

(working #install-msg)

(run Un-Path "\"(complete 90)\"")

(complete 80)

;-----------------------
; Copying locale.
;-----------------------

(if (exists "Sys:Locale" (noreq))
(
	(if (exists "LOCALE:" (noreq))
	(
		(set language
			(askoptions
				(prompt #which-language)
				(help #which-language-help)
				(choices
					"English"
					"Svenska")
					(default #default_language)
				)
		)

		(set count 0)
		(while (set lang (select count
										"english"
										"svenska"
										""))
		(
			(if (IN language count)
			(
				(if (<> count 0)
				(
					(makedir (cat "LOCALE:Catalogs/" lang))

					(copyfiles
						(source (cat "/Catalogs/" lang))
						(dest (cat "LOCALE:Catalogs/" lang))
						(all)
					)

					(run (cat Un-Path "\"(delete 'Locale:Catalogs/" lang "/cronprefs.catalog')\""))

				))
			))

			(set count (+ count 1))
		))
	))
))

(complete 88)

;----------------------
; Typing registerform.
;----------------------

(set #Regform
	(askchoice
		(prompt #RegFormPrompt)
		(default 0)
		(choices #RegFormChoices1 #RegFormChoices2)
		(help "Hjlp!!!")
))

(complete 96)

(if #Regform
(
	(if (= @language "english")
	(
		(run "type >prt: /Docs/Register_form.eng")
	))

	(if (= @language "svenska")
	(
		(run "type >prt: /Docs/Register_form.eng")
	))
))

(user 3)

(run Un-Path "\"(complete 100)\"")
(run Un-Path "\"(message '" #UnInstallFinished "')\"")
(run Un-Path "\"(exit (quiet))\"")

(complete 100)

(message (cat #Ending (substr Un-Path 7)))

(exit (quiet))